6. 手順の自動化

以下のスクリプトを使うと、手順の大半を自動化出来ます。ScanType と 2 つの Polarity line には充分注意してください。このスクリプトはそれらの設定は 行わないので、適切な訂正をしないとモニタが火を噴く可能性が高まります。

私は Xinside において "Doublescan" フラグが意味を持っているかどうか知りません。 それゆえ、もし低解像度の doublescan モードに変換しようとする場合は、 注意してください。リフレッシュレートが二倍になってしまうので、モニタが すぐに壊れてしまいます (実際、私の場合 400x300@72Hz が 400x300@144Hz に なってしまいました！)。

#!/bin/sh
##########################################################################
# XF2XInside
#
# このスクリプトは、XF86Config フォーマットの modeline を XInside の
# フォーマットに変換するものです。これは etc/Xtiminig ファイルで必要
# とされるものです。
# 
# やっつけ仕事なので、エラーチェックはほとんどしません
# (ユーザフレンドリでないなどと言わないでください)。
#
# 引数なしで実行すると、使い方を表示します。
#
#                               ( July 1996, hcz@tazlwurm.bb.bawue.de)
#
# Btw: この HOWTO の記載どおりに作成された新しいモードは、問題なく
# 機能するのですが、Xsetup のメニューが表示されません。
# なぜだか知ってる人います？
#
##########################################################################
#----------------------------------------------- ここから：
# 以下をあなたの modeline ファイルの置場所に応じて編集してください
XF=/usr/X11/lib/X11/XF86Config
if [ $# -ne 1 ] ; then
  echo "usage: ${0##*/} <mode>"
  echo " example: ${0##*/} 1024x764"
  echo -e " function: converts $XF modeline entry into\n Xinside Format (stdout)"
  exit 1
fi
egrep -i "^[\t ]*modeline.+\"$1\""  /usr/X11/lib/X11/XF86Config |
gawk '
NF < 11  { print "! invalid Modeline:\n! " $0 "\n!"; next }
{
  print "//", $0  ":"
  name = $2
  DOT_CLK = $3;
  A = $4;
  B = $5;
  C = $6;
  D = $7;
  a = $8;
  b = $9;
  c = $10;
  d = $11;
  VerFrequency =  1000000 / ((D / DOT_CLK) * d)
  print "[PREADJUSTED_TIMING]"
  printf "  PreadjustedTimingName = \"%dx%d @ %.0dHz\";\n", A, a, VerFrequency
  print "  HorPixel\t\t= " A ";"
  print "  VerPixel\t\t= " a ";"
  print "  PixelWidthRatio\t= 4;\n  PixelHeightRatio\t= 3;"
  print "  HorFrequency\t\t= " DOT_CLK / D * 1000 ";\t// kHz"
  print "  VerFrequency\t\t= " VerFrequency  ";\t// Hz"
  print "  ScanType\t\t= NONINTERLACED;\t\t// *CHECK*"
  print "  HorSyncPolarity\t= NEGATIVE;\t\t\t// *CHECK*"
  print "  VerSyncPolarity\t= NEGATIVE;\t\t\t// *CHECK*"
  print "  CharacterWidth\t= 8;"
  print "  PixelClock\t\t= " DOT_CLK ";"
  HorTotalTime = D / DOT_CLK
  print "  HorTotalTime\t\t= " HorTotalTime ";"
  print "  HorAddrTime \t\t= " A / DOT_CLK ";"
  print "  HorBlankStart\t\t= " A / DOT_CLK ";"
  print "  HorBlankTime\t\t= " D / DOT_CLK - A / DOT_CLK ";"
  print "  HorSyncStart\t\t= " B / DOT_CLK ";"
  print "  HorSyncTime\t\t= " C / DOT_CLK - B / DOT_CLK ";"
  VerTotalTime  = ( HorTotalTime * d ) / 1000
  print "  VerTotalTime\t\t= " VerTotalTime ";"
  print "  VerAddrTime\t\t= " ( HorTotalTime * a ) / 1000 ";"
  VerBlankStart = ( HorTotalTime * a ) / 1000
  print "  VerBlankStart\t\t= " VerBlankStart ";"
  print "  VerBlankTime\t\t= " VerTotalTime - VerBlankStart ";"
  print "  VerSyncStart\t\t= " ( HorTotalTime * b ) / 1000 ";"
  print "  VerSyncTime\t\t= " ( HorTotalTime * ( c - b ) ) / 1000
  print ""
}'